PKGBUILD

# Obarun        : 66 init/supervisor
# Maintainer    : Eric Vidal <eric@obarun.org>
# Maintainer    : Jean-Michel T.Dydak <jean-michel@obarun.org>
# Obarun PkgSrc : url="https://framagit.org/pkg/obextra/brltty"
#----------------
# Maintainer    :
# Contributor   :
# Arch PkgSrc   : url="https://www.archlinux.org/packages/extra/x86_64/brltty/"
#----------------
# Website       : https://brltty.app
#----------------------------------------------------------------------------
#--DESCRIPTION---------------------------------------------------------------

pkgname=brltty

pkgdesc="Braille display driver for Linux/Unix"

pkgver=6.3
pkgrel=2

url="https://brltty.app"

target="${pkgname}-${pkgver}.tar.bz2"
source=("https://brltty.app/archive/${target}"
        'brltty.sysusers'
        'brltty.tmpfiles')

#--BUILD CONFIGURATION-------------------------------------------------------

options=('!emptydirs')

makedepends=(
    'alsa-lib'
    'at-spi2-atk'
    'at-spi2-core'
    'atk'
    'cython'
    'dbus'
    'espeak-ng'
    'expat'
    'festival'
    'glib2'
    'gpm'
    'icu'
    'java-environment'
    'libxaw'
    'ncurses'
    'ocaml-ctypes'
    'ocaml-findlib'
    'speech-dispatcher'
    'flite')

#--BUILD PREPARATION---------------------------------------------------------

prepare() {
  cd "${pkgname}-${pkgver}"
  ./autogen
}


#--BUILD CONTROL-------------------------------------------------------------

path=(
    '--prefix=/usr'
    '--sysconfdir=/etc'
    '--localstatedir=/var'
    '--mandir=/usr/share/man'
    '--with-scripts-directory=/usr/lib/brltty')

flags=(
    '--with-tables-directory=/usr/share/brltty'
    '--with-writable-directory=/run/brltty'
    '--enable-gpm'
    '--disable-stripping'
    '--with-flite-voice=cmu_us_kal16')

#--BUILD---------------------------------------------------------------------

build() {
  cd "${pkgname}-${pkgver}"
  ./configure ${path[@]} ${flags[@]}

  make
}


#--PACKAGE-------------------------------------------------------------------

package() {
    depends+=(
        'libasound.so'
        'libdbus-1.so'
        'libexpat.so'
        'libgio-2.0.so'
        'libglib-2.0.so'
        'libgobject-2.0.so'
        'libicuuc.so'
        'libgpm.so'
        'libncursesw.so')

    cd "${pkgname}-${pkgver}"

    make INSTALL_ROOT="${pkgdir}" install

    make INSTALL_ROOT="${pkgdir}" install -C Autostart/Udev

    install -vDm 644 "Documents/${pkgname}.conf" -t "${pkgdir}/etc/"

    install -vDm 644 "../${pkgname}.sysusers" "${pkgdir}/usr/lib/sysusers.d/${pkgname}.conf"

    install -vDm 644 "../${pkgname}.tmpfiles" "${pkgdir}/usr/lib/tmpfiles.d/${pkgname}.conf"
}

#--INSTALL CONFIGURATION-----------------------------------------------------

arch=('x86_64')

backup=(etc/brltty.conf)

depends=(
    'bluez-libs'
    'gcc-libs'
    'glibc'
    'liblouis'
    'libspeechd'
    'pcre'
    'polkit'
    'tcl')

optdepends=('at-spi2-core: X11/GNOME Apps accessibility'
            'atk: ATK bridge for X11/GNOME accessibility'
            'espeak-ng: espeak-ng driver'
            'java-runtime: Java support'
            'libxaw: X11 support'
            'libxt: X11 support'
            'libx11: for xbrlapi'
            'libxfixes: for xbrlapi'
            'libxtst: for xbrlapi'
            'ocaml: OCaml support'
            'python: Python support'
            'speech-dispatcher: speech-dispatcher driver')


provides=('libbrlapi.so')


#--SECURITY AND LICENCE------------------------------------------------------

sha512sums=('a27236fc6211dfe1b9867871eca475a5c82471ea10c1bc3006916f9420764c6f91d5f2cfc5c44c6c76f1120f3ef21c821ca9a804d81ebcad6ecad886c2ef84ad'
            'cc2e2d5f33d4e11d6ff828aefc0773ccdc02127ce2f00649c1e3f8d4b39b90789f4a0e41385b344f850c38bd4a1df36d3d9d413a59144d431defdd343633f800'
            'a530fe66983768f9dc544af01c586abc101dfa2ed76885b4f1fd78c483b59e8445f2c0dbbfb865dd1cf2874342c346bd35ce978ab246e9cdd31d2d489a14e770')
b2sums=('ed3744173f59c85ac9e2bdef45e65dc98d178e51332f2fc0903763067c0f9a6a806c60989a36c825baa3dbdd1ed0629395318c22134413aa27791e17b3398413'
        'e6b7453360ef92254ff1049b387c9ee45f3be0e0259c9c3670154938f61ec4142b2de330401d09e1290ed9ffe8e390ede3472dab0e2f4c69b497f9ac19795aad'
        '59f50e367d2e6c6704902ebbd254232aa17c741c9a43ba27d0ebaa5fd4a86f62bc8bdd08e8e4562437dea0efa9d49845e40c022b8c4d7110675d81bf63ac4df4')


license=('LGPL2.1')