archrelease: copy trunk to multilib-testing-x86_64

git-svn-id: file:///srv/repos/svn-community/svn@665844 9fca08f4-af9d-4005-b8df-a31f2cc04f65

repos/multilib-testing-x86_64/PKGBUILD

+# Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
+
+_pkgbasename=libpulse
+pkgname=lib32-$_pkgbasename
+pkgdesc="A featureful, general-purpose sound server (32-bit client libraries)"
+pkgver=13.99.1+67+g414644dff
+pkgrel=1
+arch=(x86_64)
+url="https://www.freedesktop.org/wiki/Software/PulseAudio/"
+license=(LGPL)
+depends=(lib32-{dbus,libasyncns,libcap,libxtst,libsm,libsndfile,systemd}
+         $_pkgbasename)
+makedepends=(lib32-{speexdsp,glib2,gtk3} git meson)
+optdepends=('lib32-alsa-plugins: ALSA support')
+provides=("lib32-pulseaudio=$pkgver")
+conflicts=(lib32-pulseaudio)
+replaces=(lib32-pulseaudio)
+_commit=414644dff1abd32294db3be1fde001f56ec9e65a  # master
+source=("git+https://gitlab.freedesktop.org/pulseaudio/pulseaudio.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd pulseaudio
+  git describe --tags | sed 's/^v//;s/-/+/g'
+}
+
+prepare() {
+  cd pulseaudio
+
+  # Freeze version before patching
+  ./git-version-gen doesnt-exist >.tarball-version
+}
+
+build() {
+  export CC="gcc -m32"
+  export CXX="g++ -m32"
+  export PKG_CONFIG="i686-pc-linux-gnu-pkg-config"
+
+  arch-meson pulseaudio build \
+    --libdir /usr/lib32 \
+    --auto-features auto \
+    -D man=false \
+    -D tests=false \
+    -D avahi=disabled \
+    -D bluez5=false \
+    -D gcov=false \
+    -D pulsedsp-location='/usr/\$LIB/pulseaudio' \
+    -D stream-restore-clear-old-devices=true \
+    -D udevrulesdir=/usr/lib/udev/rules.d
+  meson compile -C build
+}
+
+check() {
+  meson test -C build --print-errorlogs
+}
+
+_pick() {
+  local f d
+  for f; do
+    d="$pkgdir/${f#$srcdir/install/}"
+    mkdir -p "$(dirname "$d")"
+    mv "$f" "$d"
+    rmdir -p --ignore-fail-on-non-empty "$(dirname "$f")"
+  done
+}
+
+package() {
+  DESTDIR="$srcdir/install" meson install -C build
+
+  cd install
+  _pick usr/lib32/libpulse{,-simple,-mainloop-glib}.so*
+  _pick usr/lib32/{cmake,pkgconfig}
+  _pick usr/lib32/pulseaudio/libpulse{dsp,common-*}.so
+}
+# vim:set sw=2 et: