PKGBUILD

# Obarun        : 66 init/supervisor
# Maintainer    : Eric Vidal <eric@obarun.org>
# Maintainer    : Jean-Michel T.Dydak <jean-michel@obarun.org>
# PkgSource     : url="https://git.obarun.org/pkg/observice/scandir-66serv"
#-----------------------------------------------------------------------------------------------

#-----------------------------------------| DESCRIPTION |---------------------------------------

pkgbase=scandir-66serv
pkgname=scandir@-66serv

pkgdesc="Service to create a nested user scandir"

pkgver=0.3.1
pkgrel=1

url="https://git.obarun.org/obmods/${pkgbase}.git"

track=tag
target="v${pkgver}"
source=("${pkgbase}::git+${url}#${track}=${target}")

#-------------------------------------| BUILD CONFIGURATION |-----------------------------------

makedepends=(
    'git'
)

#--------------------------------------------| BUILD |-------------------------------------------

build() {
    cd "${pkgbase}"

    ./configure \
        --bindir=/usr/bin \
        --with-system-service=/usr/lib/66/service \
        --with-system-module=/usr/lib/66/module
}

#-------------------------------------------| PACKAGE |------------------------------------------

package() {
    cd "${pkgbase}"

    make DESTDIR="${pkgdir}" install

    install -Dm 0644 LICENSE "${pkgdir}"/usr/share/licenses/"${pkgname}"/LICENSE

}
#------------------------------------| INSTALL CONFIGURATION |----------------------------------

arch=('x86_64')

depends=(
    '66>=0.6.0.0'
    '66-tools>=0.0.7.0'
)

optdepends=('dbus-66serv>=0.2.0: support of scandir environment configuration')

#-------------------------------------| SECURITY AND LICENCE |----------------------------------

sha512sums=('SKIP')

license=('0BSD')