PKGBUILD

# Maintainer: Eric Vidal <eric@obarun.org>
# based on the original https://git.archlinux.org/svntogit/community.git/log/trunk?h=packages/weston
# 						Maintainer: Sébastien Luttringer
# 						Contributor: Joel Teichroeb <joel@teichroeb.net>

pkgname=weston
pkgver=6.0.1
pkgrel=2
pkgdesc='Reference implementation of a Wayland compositor'
arch=('x86_64')
url='https://wayland.freedesktop.org/'
license=('MIT')
depends=('glibc' 'wayland' 'libxkbcommon' 'libinput' 'libunwind' 'pixman'
         'libdrm' 'pam' 'cairo' 'libpng' 'libjpeg-turbo' 'libwebp'
         'mesa' 'libegl' 'libgles' 'glib2' 'pango' 'lcms2' 'mtdev' 'libx11'
         'libxcb' 'dbus' 'libva' 'libxcursor' 'colord' 'freerdp')
makedepends=('wayland-protocols' 'meson' 'ninja')
source=("https://wayland.freedesktop.org/releases/$pkgname-$pkgver.tar.xz")
md5sums=('e7b10710ef1eac82258f97bfd41fe534')

prepare() {
  cd $pkgname-$pkgver
  # apply patch from the source array (should be a pacman feature)
  local src
  for src in "${source[@]}"; do
    src="${src%%::*}"
    src="${src##*/}"
    [[ $src = *.patch ]] || continue
    msg2 "Applying patch $src..."
    patch -Np1 < "../$src"
  done
}

build() {
  meson $pkgname-$pkgver build \
    --prefix=/usr \
    --libexec=lib/weston \
    -Dsimple-dmabuf-drm=auto \
    -Dsystemd=false \
    -Dlauncher-logind=false
  ninja -C build
}

package() {
  DESTDIR="$pkgdir" ninja -C build install
  # license
  install -Dm644 $pkgname-$pkgver/COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
}