From 45aa36fee85989c0b13f5d26cccbc4fe2f8d5d6a Mon Sep 17 00:00:00 2001
From: heftig <heftig@9fca08f4-af9d-4005-b8df-a31f2cc04f65>
Date: Fri, 19 Dec 2014 22:44:32 +0000
Subject: [PATCH] archrelease: copy trunk to multilib-testing-x86_64
git-svn-id: file:///srv/repos/svn-community/svn@124139 9fca08f4-af9d-4005-b8df-a31f2cc04f65
---
repos/multilib-testing-x86_64/PKGBUILD | 65 ++++++++++++++++++++++++++
1 file changed, 65 insertions(+)
create mode 100644 repos/multilib-testing-x86_64/PKGBUILD
diff --git a/repos/multilib-testing-x86_64/PKGBUILD b/repos/multilib-testing-x86_64/PKGBUILD
new file mode 100644
index 0000000..6554fe0
--- /dev/null
+++ b/repos/multilib-testing-x86_64/PKGBUILD
@@ -0,0 +1,65 @@
+# $Id$
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
+# Contributor: Daniel J Griffiths <ghost1227@archlinux.us>
+# Contributor: Corrado Primier <bardo@aur.archlinux.org>
+# Contributor: William Rea <sillywilly@gmail.com>
+
+_pkgbasename=libpulse
+pkgname=lib32-$_pkgbasename
+pkgdesc="A featureful, general-purpose sound server (32-bit client libraries)"
+pkgver=5.99.2
+pkgrel=1
+arch=(x86_64)
+url="http://www.freedesktop.org/wiki/Software/PulseAudio"
+license=(LGPL)
+depends=(lib32-libdbus lib32-json-c lib32-systemd
+ lib32-libasyncns lib32-libcap lib32-libxtst lib32-libsm lib32-libsndfile
+ $_pkgbasename)
+makedepends=(gcc-multilib libtool-multilib intltool lib32-glib2 lib32-speex lib32-gtk2 git)
+optdepends=('lib32-alsa-plugins: ALSA support')
+provides=("lib32-pulseaudio=$pkgver")
+conflicts=(lib32-pulseaudio)
+replaces=(lib32-pulseaudio)
+options=(!emptydirs !libtool)
+source=("http://freedesktop.org/software/pulseaudio/releases/pulseaudio-$pkgver.tar.xz")
+sha256sums=('877fbc19c5928ade11c948814d0d444673c39a8ec5571d331642f3327d2c86fe')
+
+_libs="libpulse.la libpulse-simple.la libpulse-mainloop-glib.la"
+_pkglibs="libpulsecommon-${pkgver%.*}.la libpulsedsp.la"
+
+prepare() {
+ cd pulseaudio-$pkgver
+}
+
+build() {
+ cd pulseaudio-$pkgver
+
+ export CC="gcc -m32"
+ export CXX="g++ -m32"
+ export PKG_CONFIG_PATH="/usr/lib32/pkgconfig"
+
+ ./configure --prefix=/usr \
+ --sysconfdir=/etc \
+ --libdir=/usr/lib32 \
+ --libexecdir=/usr/lib32 \
+ --localstatedir=/var \
+ --disable-tcpwrap \
+ --disable-bluez4 \
+ --disable-samplerate \
+ --disable-rpath \
+ --disable-default-build-tests
+
+ # fight unused direct deps
+ sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+
+ make -C src $_libs $_pkglibs
+}
+
+package() {
+ cd pulseaudio-$pkgver
+ make -j1 -C src DESTDIR="$pkgdir" \
+ lib_LTLIBRARIES="$_libs" install-libLTLIBRARIES
+ make -j1 -C src DESTDIR="$pkgdir" \
+ pkglib_LTLIBRARIES="$_pkglibs" install-pkglibLTLIBRARIES
+ make -j1 DESTDIR="$pkgdir" install-pkgconfigDATA
+}
--
GitLab