# Obarun      : 66 init/supervisor
# Maintainer  : Jean-Michel T.Dydak <jean-michel@obarun.org> <jean-michel@syntazia.org>
# Maintainer  : Eric Vidal <eric@obarun.org>
# PkgSource   : https://framagit.org/obarun-pkgbuild-extra/qt5-base
#--------------
## PkgSource  : https://www.archlinux.org/packages/extra/x86_64/qt5-base/
## Maintainer : Felix Yan <felixonmars@archlinux.org>
## Contributor: Andrea Scarpino <andrea@archlinux.org
#--------------------------------------------------------------------------------------

pkgbase=qt5-base
pkgname=(qt5-base qt5-xcb-private-headers)
_qtver=5.13.1
pkgver=${_qtver/-/}
pkgrel=3
arch=('x86_64')
url="https://www.qt.io"
license=('GPL3' 'LGPL3' 'FDL' 'custom')
pkgdesc="A cross-platform application and UI framework"
_pkgfqn="${pkgbase/5-/}-everywhere-src-${_qtver}"
source=("http://download.qt.io/official_releases/qt/${pkgver%.*}/${_qtver}/submodules/${_pkgfqn}.tar.xz"
		'qtbug-77364.patch')
conflicts=(
	'qtchooser')

groups=(
	'qt'
	'qt5')

depends=(
	'libjpeg-turbo'
	'xcb-util-keysyms'
	'xcb-util-renderutil'
	'libgl'
	'fontconfig'
	'xdg-utils'
	'shared-mime-info'
	'xcb-util-wm'
	'libxrender'
	'libxi'
	'sqlite'
	'xcb-util-image'
	'mesa'
	'tslib'
	'libinput'
	'libxkbcommon-x11'
	'libproxy'
	'libcups'
	'double-conversion')

makedepends=(
	'libfbclient'
	'mariadb-libs'
	'sqlite'
	'unixodbc'
	'postgresql-libs'
	'alsa-lib'
	'gst-plugins-base-libs'
	'gtk3'
	'libpulse'
	'cups'
	'freetds'
	'vulkan-headers')

optdepends=(
	'qt5-svg: to use SVG icon themes'
	'qt5-translations: for some native UI translations'
	'postgresql-libs: PostgreSQL driver'
	'mariadb-libs: MariaDB driver'
	'unixodbc: ODBC driver'
	'libfbclient: Firebird/iBase driver'
	'freetds: MS SQL driver'
	'gtk3: GTK platform plugin')

#--------------------------------------------------------------------------------------
prepare() {
	cd ${_pkgfqn}

	## Build qmake using Arch {C,LD}FLAGS
	## This also sets default {C,CXX,LD}FLAGS for projects built using qmake
	sed -i -e "s|^\(QMAKE_CFLAGS_RELEASE.*\)|\1 ${CFLAGS}|" \
	  mkspecs/common/gcc-base.conf
	sed -i -e "s|^\(QMAKE_LFLAGS_RELEASE.*\)|\1 ${LDFLAGS}|" \
	  mkspecs/common/g++-unix.conf
	 
	patch -p1 -i ../qtbug-77364.patch # Fix keyboard input in webengine
}

build() {
	cd ${_pkgfqn}

	#echo "INCLUDEPATH += /usr/include/openssl" >> src/network/network.pro
	#export OPENSSL_LIBS='-L/usr/lib -lssl -lcrypto'

	./configure \
		-confirm-license -opensource -v \
		-prefix /usr \
		-docdir /usr/share/doc/qt \
		-headerdir /usr/include/qt \
		-archdatadir /usr/lib/qt \
		-datadir /usr/share/qt \
		-sysconfdir /etc/xdg \
		-examplesdir /usr/share/doc/qt/examples \
		-plugin-sql-{psql,mysql,sqlite,odbc,ibase} \
		-system-sqlite \
		-openssl-linked \
		-nomake examples \
		-no-rpath \
		-optimized-qmake \
		-dbus-linked \
		-system-harfbuzz \
		-no-mimetype-database \
		-no-use-gold-linker \
		-reduce-relocations
	make
}

package_qt5-base() {
	pkgdesc='A cross-platform application and UI framework'

	cd ${_pkgfqn}
	make INSTALL_ROOT="${pkgdir}" install

	install -Dm644 LICENSE* -t "$pkgdir"/usr/share/licenses/$pkgbase

	## Drop QMAKE_PRL_BUILD_DIR because reference the build dir
	find "${pkgdir}/usr/lib" -type f -name '*.prl' \
	 -exec sed -i -e '/^QMAKE_PRL_BUILD_DIR/d' {} \;

	## Fix wrong qmake path in pri file
	sed -i "s|${srcdir}/${_pkgfqn}|/usr|" \
	 "${pkgdir}"/usr/lib/qt/mkspecs/modules/qt_lib_bootstrap_private.pri

	## Symlinks for backwards compatibility
	for b in "${pkgdir}"/usr/bin/*; do
	 ln -s $(basename $b) "${pkgdir}"/usr/bin/$(basename $b)-qt5
	done
}

package_qt5-xcb-private-headers() {
	pkgdesc='Private headers for Qt5 Xcb'

	depends=("qt5-base=$pkgver")
	optdepends=()
	groups=()
	conflicts=()

	cd ${_pkgfqn}
	install -d -m755 "$pkgdir"/usr/include/qtxcb-private
	cp -r src/plugins/platforms/xcb/*.h "$pkgdir"/usr/include/qtxcb-private/
}

#--------------------------------------------------------------------------------------
sha512sums=('33b74cd6e8a7671b6f621ffee1e0d572ad52463eab1f041e11f769fe01706ce187601bfe93211cd00b0138a3ff9698d5138476de7c141d52f4ec330672709580'
            '1174da76c8f2df71f8778b3ec6a5d5171b203f519652650ca099446207a53fd052b450c1ae944e70a963695f90e32a22ecb957a1738054c05eb731521247f28c'
            '1785bfde1685cb4e8fc0128ac6e338761ec00d0f70a68b97ba176b01ab539178ac3746eb67eed3c2039c30f076475e2e87bc31fe2a9b7fce499e6324646cad31'
            'af0c1101bf001a8ba566859eeed083dcde6dc8b32edb8eb0de6672045622167a462f2f16cb0f208fd46bfc1847c68d44fb0ec45a0b729436b40aafa08334c56c')